...	(prior code here)
	;-------------------------------;
	call	Print_Immediate		; call print immediate string to current selected output 
	ds	"Sram OK"		; the return address actually points to the string, not code
	db	0			; string termination sentinel
	;-------------------------------;
...	(next code here)		; this the the next code instruction and PRTIMM pushes this address 
					; onto the stack and returns
...
;-----------------------;---------------; 
			; print the string at the return address to the selected portal.
Print_Immediate:	; then restore the return address or program counter (PC) to the next instruction below the CALL.
			; this code located with jump relative internal accessible range.
			;---------------; 
	pop	hl			; popped return address is actually the address of the immediate string
	jr	GetChr			; jump into loop to process next character from string
	;-------------------------------;
SndChr:	push	hl			; save the message character pointer on the stack while sending chr to portal
;;;	call	Serial			; uncomment if sending character to terminal, display or printer
	call	Morse			; uncomment if sending character to Morse coder
	pop	hl			; restore the message character pointer
				;-------;
GetChr:	ld	a,(hl)			; get next string character
	inc	hl			; bump pointer to next address
	cp	0			; test for null termination
	jr	nz,SndChr		; jump if another character to send it to portal
				;-------;
	jp	(hl)			; else short-return, hl->pc
;-----------------------;---------------; 
			; Next block is a Table of 36 acceptible ascii characters that can be sent via Morse code. 
Tmorse:			; Lowercase letters will be converted into upper case letters before using this table.
			; The letters are ordered by English frequency-of-use to speed up searches.
			; The 10 numbers are simply appended last. Separating the numbers and punctuations not worthwhile here.
			; If the character is not found within the following string, control will return to Print_Immediate
			; The English Letter Order is from:
			;	"CRYPTANALYSIS, a study of ciphers and their solution"
			;	by Helen Fouche Gaines
			; Most books on cryptanalysis have a table like this.
			; Numbers are mostly constidered random, except ZERO, which appears often like "$1.00"
	;---------------;---------------; 
	ds	"ETAONISRHLDCUPFMWYBGVKQXJZ0123456789"
	;---------------;---------------; 
			; Table of 36 encoded Morse code characters in the same order of the ascii search.
			; When a acceptible character is found in Tmorse, its encoded Morse code character
			; is simple found by adding another 36 to the HL pointer.
			; The Morse code character encoding supports up to 5 Morse keystroke (per character).
			; It does not support any punctuation, not worthwhile here.
			;               _______________________________________
			; ENCODING:    | 0="."  1="-"  0=unused | Keycount 1:5 |
			;              | b7 | b6 | b5 | b4 | b3 | b2 | b1 | b0 |
			; "C" = _._. = |__1_|__0_|__1_|__0_|__0_|__1_|__0_|__0_| = A4h = dash dot dash dot (b3 is unused)
	;---------------;---------------;                   "C"
	db	01h,81h,42h,E3h,82h,02h,03h,43h,04h,44h,83h,A4h,23h,64h,24h,C2h,63h,B4h
	db	84h,C3h,14h,A3h,D4h,94h,74h,C4h,FDh,7Dh,3Dh,1Dh,0Dh,05h,85h,C5h,E5h,F5h
;-------;---------------;---------------; 
			; Register A holds the ascii character from the print_immediate string
Morse:			; If the character is not found within the Tascii block, the program will quickly return
			;---------------;
	cp	20h			; if a space is found, add a Tgap3 delay between words
	jp	z,InsertGap3		; spaces insert a delay between Morse words then return to Print_Immediate
					; search character is in register a. make lowercase letters uppercase.
	cp	5Fh			; if greater than 5Fh convert to uppercase. non-letters are rejected within 7Fh:40h
	jr	m,ScanChrs		; skif not lowercase range, skips mask if uppercase or numbers
	and	11011111b		; lowercaser letters become uppercase letters, b7 ascii should always be a 0
ScanChrs:	;-----------------------; scan the Tascii string for letters and numbers that Morse will send
	ld	hl,Tascii		; prepare search: hl points to ascii tables of Morse code characters acceptible
	ld	bc,36			; prepare search: bc is the size of ascii table search
	cpir				; z flag if found, else bc=0 if not found
	ret	nz			; return on nz, character not found in allowable Morse set. return ignores the character.
				;-------;
	ld	bc,36			; value to bump pointer from character to its Morse encoded byte
	add	hl,bc			; hl now points to Morse encoded pattern/count data byte
	ld	a,00000111b		; mask for get the Morse count field only
	and	a,(hl)			; register a now holds only the Morse count byte
	ld	b,a			; move the Morse count to b (counter for djnz loop)
	ld	a,(hl)			; read again for the dot/dash pattern + unused 0s + Morse counter
KeyTheChr:	;-----------------------; Key the Morse code pattern of dots and dashes for the accepted ascii character
	rlca				; shift next dot/dash into carry flag
	ld	d,TDot			; set delay time for dots by default
	jr	nc,KeyingNow		; skif not carry because T_Dot is loaded
	ld	d,TDash			; else set delay time for dashes (3 times a dot duration)
KeyingNow:	;-----------------------;
	[INSERT: Morse signal ON]	; start the Morse key (a dot or a dash)
	call	Delay			; delay time based on register D
	[INSERT: Morse signal OFF]	; end the current Morse key
	ld	d,TGap1			; set delay time between dots and dashes
	call	Delay			; delay time based on register D
	djnz	KeyTheChr		; send next Morse keystroke until b=0
				;-------; the character has been sent
	ld	d,TGap2			; load gap between characters
	call	Delay			; delay time based on register D
	ret				; exit Morse, character sent, return to Print_Immediate for next character
	;-------------------------------;
InsertGap3:				;
	ld	d,TGap3			; load gap between words (when a space is detected)
	call	Delay			; delay time based on register D
	ret				; exit Morse, delay between words done, return to Print_Immediate for next character
;---------------------------------------;