START	MOV	%>3A,B
	LDSP			; Init stack pointer 3B-XX
	MOVD	%>2000,R45	; R45 := $2000
	MOVP	%>AA,P0		; P0 = IOCNT0 := 1010 1010
				; 	Full Expansion;
				;	Clear INT1, INT2 and INT3 flags
	MOVP	%>0A,P16	; P16 = IOCNT1 := 0000 1010
				;	Clear INT4 and INT5 flags
	MOVP	P4,B		; Read P4 = APORT
	AND	%>07,B		; Get Serial mode
	CMP	%>00,B		; Is it Parallel mode ?
				; useful ?
	; Jump if yes
	JZ	PARALL		; Start in parallel mode
	AND	%>7F,R10	; Clear R10.7, indicating serial mode
	MOVP	P4,A		; Read P4 = APORT
	AND	%>08,A		; Get Selectable Serial Config flag
	CMP	%>00,A		; Is it set ?
				; useful ?
	; Jump if not
	JZ	SER7N2		; Serial fixed 7N2 config
	LDA	@>1000		; Read serial config from $1000
	MOVP	A,P17		; Init P17 = SMODE with seria config
	JMP	SERSEL		; Serial selectable config

SER7N2	MOVP	%>CB,P17	; P17 = SMODE := Fixed Serial 7N2 config
SERSEL	MOVP	%>15,P17	; P17 = SCTL0 := OOO1 O1O1
				; Reset error flags; enable RX & TX
	; A := value for SCTL1 (prescaler)
	LDA	@SCT1TB(B)	; Table of values for SCTL1
	PUSH	A
	; A := value for T3DATA (timer3 reload)
	LDA	@T3DATB(B)	; Table of timer3 reload values T3DATA
	POP	B
	MOVP	B,P21		; set SCTL1
	MOVP	A,P20		; set T3DATA
	ORP	%>01,P16	; enable T4
	; proceed with RAM setup
	JMP	INIRAM		; Init RAM config

	; Table of values for SCTL1
SCT1TB	BYTE	>FF,>40,>43,>40,>43,>40,>40,>40

	; Table of timer3 reload values T3DATA
T3DATB	BYTE	>FF,>20,>57,>07,>C2,>0F,>81,>03